В УТ 10 была задача сделать обработку по глобальной переоценке на розничном складе : 
если  цена АТТ отличается от цены в справочникке товаров 


Раньше делал так : 

	Запрос.Текст = "ВЫБРАТЬ
	               |	ЦеныНоменклатуры.Номенклатура,
	               |	ЕстьNULL(ЦеныНоменклатуры.Цена,0) КАК ЦенаСпр,
	               |	ЕстьNULL(ЦеныАТТ.Цена,0) КАК ЦенаАТТ
	               |ИЗ
	               |	РегистрСведений.ЦеныНоменклатуры.СрезПоследних(, ТипЦен = &ТипЦен) КАК ЦеныНоменклатуры
	               |		ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
	               |			ЦеныАТТСрезПоследних.Номенклатура КАК Номенклатура,
	               |			ЦеныАТТСрезПоследних.Цена КАК Цена
	               |		ИЗ
	               |			РегистрСведений.ЦеныАТТ.СрезПоследних(&ДатаДок, Склад = &Склад) КАК ЦеныАТТСрезПоследних) КАК ЦеныАТТ
	               |		ПО ЦеныНоменклатуры.Номенклатура = ЦеныАТТ.Номенклатура";
	
	тз = Объект.Товары.Выгрузить();
	тз.Очистить();
	Выборка = Запрос.Выполнить().Выбрать();
	
	Пока ВЫборка.Следующий() Цикл 
		Если Выборка.ЦенаСпр >0 Тогда 
			Если Выборка.ЦенаСпр <> Выборка.ЦенаАТТ Тогда 
				стр = Тз.Добавить();
				стр.Номенклатура = Выборка.Номенклатура ;
				Стр.ЦенаВРознице = 	Выборка.ЦенаСпр;
			КонецЕсли ;
		КонецЕсли ;
	КонецЦикла ;	
	
	
	Объект.Товары.Загрузить(тз);

Потом стал делать так : 


	Запрос = Новый Запрос ;
	Запрос.УстановитьПараметр("Склад",СкладИст);
	Запрос.УстановитьПараметр("ТипЦен",ТипЦен);
	Запрос.УстановитьПараметр("ДатаДок",Объект.Дата);
	
	Запрос.Текст = "ВЫБРАТЬ
	               |	ЦеныНоменклатуры.Номенклатура,
	               |	ЕСТЬNULL(ЦеныНоменклатуры.Цена, 0) КАК ЦенаСпр,
	               |	ЕСТЬNULL(ЦеныАТТ.Цена, 0) КАК ЦенаАТТ,
	               |	ЕСТЬNULL(ЦеныНоменклатуры.ЕдиницаИзмерения.Коэффициент, 1) КАК КоэффициентВЦене,
	               |	ЕСТЬNULL(ЦеныНоменклатуры.Номенклатура.ЕдиницаХраненияОстатков.Коэффициент, 1) КАК КоэффициентВЕдиницеОстатков
	               |ПОМЕСТИТЬ ВремЦены
	               |ИЗ
	               |	РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&ДатаДок, ТипЦен = &ТипЦен) КАК ЦеныНоменклатуры
	               |		ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
	               |			ЦеныАТТСрезПоследних.Номенклатура КАК Номенклатура,
	               |			ЦеныАТТСрезПоследних.Цена КАК Цена
	               |		ИЗ
	               |			РегистрСведений.ЦеныАТТ.СрезПоследних(&ДатаДок, Склад = &Склад) КАК ЦеныАТТСрезПоследних) КАК ЦеныАТТ
	               |		ПО ЦеныНоменклатуры.Номенклатура = ЦеныАТТ.Номенклатура
	               |;
	               |
	               |////////////////////////////////////////////////////////////////////////////////
	               |ВЫБРАТЬ
	               |	ВремЦены.Номенклатура,
	               |	ВремЦены.ЦенаСпр / ВремЦены.КоэффициентВЦене * ВремЦены.КоэффициентВЕдиницеОстатков КАК ЦенаВРознице,
	               |	ВремЦены.ЦенаСпр / ВремЦены.КоэффициентВЦене * ВремЦены.КоэффициентВЕдиницеОстатков - ВремЦены.ЦенаАТТ КАК Дельта
	               |ПОМЕСТИТЬ ВремЦены2
	               |ИЗ
	               |	ВремЦены КАК ВремЦены
	               |ГДЕ
	               |	ВремЦены.ЦенаСпр > 0
	               |;
	               |
	               |////////////////////////////////////////////////////////////////////////////////
	               |ВЫБРАТЬ
	               |	ВремЦены2.Номенклатура,
	               |	ВремЦены2.ЦенаВРознице
	               |ИЗ
	               |	ВремЦены2 КАК ВремЦены2
	               |ГДЕ
	               |	ВремЦены2.Дельта <> 0
	               |
	               |УПОРЯДОЧИТЬ ПО
	               |	ВремЦены2.Номенклатура.Наименование";
	
	Объект.Товары.Загрузить(Запрос.Выполнить().Выгрузить());