ВЫБРАТЬ
	АналитикаУчетаНоменклатуры.Номенклатура КАК Номенклатура,
	АналитикаУчетаНоменклатуры.Характеристика КАК Характеристика,
	АналитикаУчетаНоменклатуры.КлючАналитики КАК КлючАналитики
ПОМЕСТИТЬ ВТ_Номенклатура
ИЗ
	РегистрСведений.АналитикаУчетаНоменклатуры КАК АналитикаУчетаНоменклатуры
ГДЕ
	АналитикаУчетаНоменклатуры.Номенклатура В ИЕРАРХИИ(&Сезон)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	СУММА(ЕСТЬNULL(ТоварыНаСкладахОстаткиИОбороты.ВНаличииПриход, 0)) КАК Приход,
	ТоварыНаСкладахОстаткиИОбороты.Номенклатура КАК Номенклатура,
	ТоварыНаСкладахОстаткиИОбороты.Характеристика КАК Характеристика
ПОМЕСТИТЬ ВТ_Приход
ИЗ
	РегистрНакопления.ТоварыНаСкладах.ОстаткиИОбороты(
			ДАТАВРЕМЯ(1, 1, 1),
			&ДатаКонца,
			Регистратор,
			ДвиженияИГраницыПериода,
			Номенклатура В
				(ВЫБРАТЬ
					Вт_Номенклатура.Номенклатура
				ИЗ
					Вт_Номенклатура)) КАК ТоварыНаСкладахОстаткиИОбороты
ГДЕ
	(ТоварыНаСкладахОстаткиИОбороты.Регистратор ССЫЛКА Документ.ПоступлениеТоваровУслуг
			ИЛИ ТоварыНаСкладахОстаткиИОбороты.Регистратор ССЫЛКА Документ.ВводОстатков)
	И НЕ ТоварыНаСкладахОстаткиИОбороты.Склад В (&ИсключитьСклад)

СГРУППИРОВАТЬ ПО
	ТоварыНаСкладахОстаткиИОбороты.Номенклатура,
	ТоварыНаСкладахОстаткиИОбороты.Характеристика
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ТоварыНаСкладахОстатки.Номенклатура КАК Номенклатура,
	ТоварыНаСкладахОстатки.Характеристика КАК Характеристика,
	СУММА(ЕСТЬNULL(ТоварыНаСкладахОстатки.ВНаличииОстаток, 0)) КАК Остатки
ПОМЕСТИТЬ ВТ_Остатки
ИЗ
	РегистрНакопления.ТоварыНаСкладах.Остатки КАК ТоварыНаСкладахОстатки
ГДЕ
	НЕ ТоварыНаСкладахОстатки.Склад В (&ИсключитьСклад)

СГРУППИРОВАТЬ ПО
	ТоварыНаСкладахОстатки.Номенклатура,
	ТоварыНаСкладахОстатки.Характеристика
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	Продажи.АналитикаУчетаНоменклатуры КАК АналитикаУчетаНоменклатуры,
	СУММА(Продажи.КоличествоОборот) КАК КоличествоОборот,
	СРЕДНЕЕ(ВЫБОР
			КОГДА ЕСТЬNULL(Продажи.КоличествоОборот, 0) = 0
				ТОГДА 0
			ИНАЧЕ ВЫРАЗИТЬ(Продажи.СуммаВыручкиОборот / Продажи.КоличествоОборот КАК ЧИСЛО(15, 2))
		КОНЕЦ) КАК ЦенаПродажи
ПОМЕСТИТЬ ВТ_Продажи
ИЗ
	РегистрНакопления.ВыручкаИСебестоимостьПродаж.Обороты(
			&ДатаНачала,
			&ДатаКонца,
			Регистратор,
			АналитикаУчетаНоменклатуры В
				(ВЫБРАТЬ
					ВТ_Номенклатура.КлючАналитики
				ИЗ
					ВТ_Номенклатура)) КАК Продажи
ГДЕ
	НЕ Продажи.Регистратор ССЫЛКА Документ.РеализацияТоваровУслуг
	И НЕ Продажи.Склад В (&ИсключитьСклад)

СГРУППИРОВАТЬ ПО
	Продажи.АналитикаУчетаНоменклатуры
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_Номенклатура.Номенклатура КАК Номенклатура,
	ВТ_Номенклатура.Характеристика КАК Характеристика,
	МАКСИМУМ(ЕСТЬNULL(ВТ_Приход.Приход, 0)) КАК Приход,
	МАКСИМУМ(ЕСТЬNULL(ВТ_Продажи.КоличествоОборот, 0)) КАК Продажи,
	МАКСИМУМ(ЕСТЬNULL(ВТ_Продажи.ЦенаПродажи, 0)) КАК ЦенаПродажи,
	МАКСИМУМ(ЕСТЬNULL(ВТ_Остатки.Остатки, 0)) КАК Остатки
ПОМЕСТИТЬ ВТ_ПродажиОстатки
ИЗ
	ВТ_Номенклатура КАК ВТ_Номенклатура
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Приход КАК ВТ_Приход
		ПО ВТ_Номенклатура.Номенклатура = ВТ_Приход.Номенклатура
			И ВТ_Номенклатура.Характеристика = ВТ_Приход.Характеристика
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Продажи КАК ВТ_Продажи
		ПО ВТ_Номенклатура.КлючАналитики = ВТ_Продажи.АналитикаУчетаНоменклатуры
		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Остатки КАК ВТ_Остатки
		ПО ВТ_Номенклатура.Номенклатура = ВТ_Остатки.Номенклатура
			И ВТ_Номенклатура.Характеристика = ВТ_Остатки.Характеристика

СГРУППИРОВАТЬ ПО
	ВТ_Номенклатура.Номенклатура,
	ВТ_Номенклатура.Характеристика
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_ПродажиОстатки.Номенклатура КАК Номенклатура,
	ВТ_ПродажиОстатки.Характеристика КАК Характеристика,
	ВТ_ПродажиОстатки.Приход КАК Приход,
	ВТ_ПродажиОстатки.Продажи КАК Продажи,
	ВТ_ПродажиОстатки.ЦенаПродажи КАК ЦенаПродажи,
	0 КАК ЦенаЗакупки,
	0 КАК ЦенаЕвро,
	0 КАК ЦенаРозничная,
	ВТ_ПродажиОстатки.Остатки КАК Остатки
ПОМЕСТИТЬ ВТ_Итоговая
ИЗ
	ВТ_ПродажиОстатки КАК ВТ_ПродажиОстатки

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ЦеныНоменклатурыСрезПервых.Номенклатура,
	ЦеныНоменклатурыСрезПервых.Характеристика,
	0,
	0,
	0,
	ЦеныНоменклатурыСрезПервых.Цена,
	0,
	0,
	0
ИЗ
	РегистрСведений.ЦеныНоменклатуры.СрезПервых(
			,
			Номенклатура В
					(ВЫБРАТЬ
						ВТ_Номенклатура.Номенклатура
					ИЗ
						ВТ_Номенклатура)
				И ВидЦены = &Закупочная) КАК ЦеныНоменклатурыСрезПервых

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ЦеныНоменклатурыСрезПервых.Номенклатура,
	ЦеныНоменклатурыСрезПервых.Характеристика,
	0,
	0,
	0,
	0,
	ЦеныНоменклатурыСрезПервых.Цена,
	0,
	0
ИЗ
	РегистрСведений.ЦеныНоменклатуры.СрезПервых(
			,
			Номенклатура В
					(ВЫБРАТЬ
						ВТ_Номенклатура.Номенклатура
					ИЗ
						ВТ_Номенклатура)
				И ВидЦены = &Евровая) КАК ЦеныНоменклатурыСрезПервых

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ЦеныНоменклатурыСрезПоследних.Номенклатура,
	ЦеныНоменклатурыСрезПоследних.Характеристика,
	0,
	0,
	0,
	0,
	0,
	ЦеныНоменклатурыСрезПоследних.Цена,
	0
ИЗ
	РегистрСведений.ЦеныНоменклатуры.СрезПоследних(
			,
			Номенклатура В
					(ВЫБРАТЬ
						ВТ_Номенклатура.Номенклатура
					ИЗ
						ВТ_Номенклатура)
				И ВидЦены = &Розничная) КАК ЦеныНоменклатурыСрезПоследних
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_Итоговая.Номенклатура КАК Номенклатура,
	ВТ_Итоговая.Характеристика КАК Характеристика,
	СУММА(ВТ_Итоговая.Приход) КАК Приход,
	СУММА(ВТ_Итоговая.Продажи) КАК Продажи,
	СУММА(ВТ_Итоговая.ЦенаПродажи) КАК ЦенаПродажи,
	СУММА(ВТ_Итоговая.ЦенаЗакупки) КАК ЦенаЗакупки,
	СУММА(ВТ_Итоговая.ЦенаЕвро) КАК ЦенаЕвро,
	СУММА(ВТ_Итоговая.ЦенаРозничная) КАК ЦенаРозничная,
	СУММА(ВТ_Итоговая.ЦенаПродажи * ВТ_Итоговая.Продажи) КАК СуммаПродажи,
	СУММА(ВТ_Итоговая.Остатки) КАК Остатки
ИЗ
	ВТ_Итоговая КАК ВТ_Итоговая

СГРУППИРОВАТЬ ПО
	ВТ_Итоговая.Номенклатура,
	ВТ_Итоговая.Характеристика

УПОРЯДОЧИТЬ ПО
	Номенклатура,
	Характеристика