[ Вопрос дня ] Как программно настроить оформление заголовка у группировки полей ресурсов в отчете на СКД?

Доброго дня, коллеги!

Наверняка среди ваших заказчиков найдутся такие, которым очень важен внешний вид разрабатываемого продукта, с ними очень долго и подробно согласовывается цвет, размер, порядок и прочие “бантики”.  Этого может требовать специфика бизнеса клиента или его личностные характеристики. Чтобы не раздражаться и уверенно отвечать “Ок. Без проблем. Я это сделаю” приходите на курс по СКД.

Вопрос

Ответ

Добрый день!

Для этого можно использовать прием из практического задания 17.1 – программная работа с макетом компоновки.

Создадим в настройках компоновки группу Обороты:

В модуле объекта реализуем собственный вывод отчета, для ячейки со значением Обороты выполним центрирование:

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

    СтандартнаяОбработка = Ложь;
   
    Массив = Новый Массив;
    НастройкиКомпоновки = КомпоновщикНастроек.ПолучитьНастройки();

    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиКомпоновки, ДанныеРасшифровки);

    Для Каждого ТекМакет Из МакетКомпоновки.Макеты Цикл

        Если НЕ ТипЗнч(ТекМакет.Макет) = Тип("МакетОбластиКомпоновкиДанных") Тогда
            Продолжить;
        КонецЕсли;

        Для Каждого Макет Из ТекМакет.Макет Цикл
           
            Для Каждого Ячейка Из Макет.Ячейки Цикл
                Для Каждого Элемент Из Ячейка.Элементы Цикл
                   
                    Если Элемент.Значение = "Обороты" Тогда

                        Параметр = Ячейка.Оформление.Элементы.Найти(Новый ПараметрКомпоновкиДанных("ГоризонтальноеПоложение"));
                        Параметр.Значение = ГоризонтальноеПоложение.Центр;
                        Параметр.Использование = Истина;

                    КонецЕсли;
                   
                КонецЦикла;
            КонецЦикла;
           
        КонецЦикла;

    КонецЦикла;

    ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки);

    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
    ПроцессорВывода.Вывести(ПроцессорКомпоновки);

КонецПроцедуры

Получится вот такой отчет: