17 вопросов и ответов по СКД, проектированию форм, навигации, панелям и т.п.

Как мы уже писали, “закармливать” видео пока не будем :)

Зато мы просмотрели вопросы, которые разбирали в Мастер-группах и выбрали несколько “общественно полезных” :)

Немного причесали, и – готово, можно читать:

Несколько вопросов из Мастер-группы курса
Профессиональная разработка интерфейсов и форм в 1С:Предприятие 8.3

Вопрос № 1:

Можно ли из модуля объекта вывести сообщение с привязкой к реквизиту управляемой формы?

MG-Questions-Interfaces-01

Ответ:

Можно. Пример кода:

Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = “Текст сообщения”;
Сообщение.Поле = “ИмяРеквизитаФормы”;
Сообщение.Сообщить();

Вопрос 2

Прошу на примере УТ 11 (см. скриншот) пояснить, как быстро найти команду, отображенную в командном интерфейсе?

MG-Questions-Interfaces-02

Ответ:

Окно командного интерфейса подсистемы, которое приведено на скриншоте, не подходит для этих целей. Для поиска команды следует использовать окно Все подсистемы.

MG-Questions-Interfaces-03

Необходимо в дереве найти интересующую команду и вызвать в контекстном меню пункт Найти в дереве:

MG-Questions-Interfaces-04

Вопрос 3

Есть управляемая форма документа с табличной частью, где заполнена колонка «Номенклатура».

Необходимо программно «сымитировать» интерактивный выбор номенклатуры, чтобы при этом сработали соответствующие обработчики в каждой строке, как будто пользователь выбрал эту же номенклатурную позицию вручную.

Ответ:

Да, это возможно. Вот программный код, который это реализует:

&НаКлиенте
Процедура КомандаПересчетСтрок(Команда)
   Для каждого Стр Из Объект.Товары Цикл
      Элементы.Товары.ТекущаяСтрока = Стр.ПолучитьИдентификатор();
      Элементы.Товары.ТекущийЭлемент = Элементы.ТоварыНоменклатура;
      Элементы.Товары.ИзменитьСтроку();
      ФормаВыбора = ПолучитьФорму(“Справочник.Номенклатура.ФормаВыбора”
             ,,Элементы.Товары.ТекущийЭлемент);
      ФормаВыбора.ОповеститьОВыборе(Стр.Номенклатура);
      Элементы.Товары.ЗакончитьРедактированиеСтроки(Ложь);
  КонецЦикла;
КонецПроцедуры

Стоит отметить, что данный программный код будет приводить к множественным обращениям к серверу, что серьезно скажется на его производительности.

Поэтому этот код следует применять только в крайних случаях, например, когда нужно срочно выполнить пересчет строк табличной части в зависимости от выбранной номенклатуры, а времени на разбор логики работы формы нет.

Вопрос 4

Как можно на командной панели формы разместить две команды так, чтобы первая из них занимала крайнее левое положение, а вторая – крайнее правое?

MG-Questions-Interfaces-05

Ответ:

Чтобы реализовать такое размещение, необходимо:

  • Выключить автозаполнение командной панели формы
  • Создать 2 командных панели и сгруппировать их горизонтально
  • На первой панели необходимо разметить команды, которые должны быть выровнены по левому краю, а на второй панели – по правому краю.
  • В свойствах 2-й панели следует включить выравнивание по правому краю.

MG-Questions-Interfaces-06

Вопрос 5

В процессе выполнения кода создается текстовый файл. По окончании формирования файла используется метод ПоказатьОповещениеПользователя().

Можно ли в этом методе создать гиперссылку, при переходе по которой будет открываться созданный файл?

Ответ:

Стандартно такой возможности нет, но можно предложить следующий вариант решения задачи.

Можно создать общую форму ФормаТекстовогоДокумента, клиентскую глобальную переменную глТекстовыйДокумент и выводить оповещение следующим образом:

глТекстовыйДокумент = “Текст из файла”;
ПоказатьОповещениеПользователя(“Текст оповещения”,
          “e1cib/app/ОбщаяФорма.ФормаТекстовогоДокумента”);

При переходе по ссылке будет открываться общая форма, где из глобальной переменной глТекстовыйДокумент можно получить текст для отображения.

Вопрос 6

Подскажите, пожалуйста, как убрать контекстное меню элемента формы.

В палитре свойств у элемента управления формы и у реквизита подходящих по смыслу настроек не вижу, может быть, не заметил.

Этот код не работает:

Элементы.СписокВыбранныхЗначенийКонтекстноеМеню.Видимость = Ложь;

Ответ:

Необходимо в контекстном меню включить отображение командной панели:

MG-Questions-Interfaces-07

После чего в свойствах контекстного меню нужно выключить Автозаполнение:

MG-Questions-Interfaces-08

Вопрос 7

Подскажите, можно ли получить владельца списка подчиненного справочника, если список пустой?

Например, в БП3 выбрал контрагента, перешел на вкладку «Договоры» – список пуст.

Как получить ссылку на контрагента?

Ответ:

Так как в форме контрагента при переходе по команде Договоры открывается форма списка справочника «Договоры» с отбором по текущему контрагенту, значение контрагента можно получить 2 способами:

1-й способ – получение контрагента из параметров открываемой формы, можно использовать только в обработчике ПриСозданииНаСервере:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
   Владелец = Неопределено;
   Параметры.Отбор.Свойство(“Владелец”, Владелец);
КонецПроцедуры

2-й способ – получение контрагента из отбора по владельцу, размещенного в фиксированных настройках:

ЭлементыОтбора = Список.Отбор.Элементы;
Владелец = Неопределено;
ПолеВладелец = Новый ПолеКомпоновкиДанных(“Владелец”);
Для каждого ЭлементОтбора Из ЭлементыОтбора Цикл
    Если ТипЗнч(ЭлементОтбора)=Тип(“ЭлементОтбораКомпоновкиДанных”) и
       ЭлементОтбора.ЛевоеЗначение = ПолеВладелец Тогда
         Владелец = ЭлементОтбора.ПравоеЗначение;
    КонецЕсли;
КонецЦикла;

Вопрос 8

С помощью метода ЗапуститьПриложение() запускаю другую базу, в которой должна выполниться некоторая обработка.

Вот программный код:

КоманднаяСтрока = “C:\Program Files (x86)\1cv82\common\1cestart.exe ENTERPRISE /S SRV2008R2:1543\Roznica /n AutoExchange /p Qwerty123! /Execute C:\ОбменУТРТ\ObmenUsers.epf /c “+КодРеглЗадания;

ЗапуститьПриложение(КоманднаяСтрока,,Истина);

Программный код должен продолжить свое исполнение только после завершения этого приложения.

Однако, несмотря на параметр ДождатьсяЗавершения, равный Истине, следующие команды начинают выполняться сразу же.

Каким образом можно дождаться завершения работы запущенной базы?

Ответ:

Все дело в том, что 1cestart.exe — это универсальная программа запуска, целью которой является запуск толстого или тонкого клиента нужной версии.

Ничего удивительного в том, что 1cestart.exe закрывается, нет. Поэтому лучше запускать нужный клиент напрямую.

Например, для версии 8.2.19.83 строка запуска толстого клиента:

КоманднаяСтрока = “c:\Program Files (x86)\1cv82\8.2.19.83\bin\1cv8.exe ENTERPRISE …”;

Вопрос 9

Можно ли выключить видимость у «Панель навигации и действий» по умолчанию для новых пользователей?

Ответ:

Для этого потребуется программным способом устанавливать настройки текущего пользователя при первом входе в базу.

Сделать это можно только на сервере, поэтому эффективнее всего использовать «Модуль сеанса», так как его код исполняется на стороне сервера до выполнения кода других модулей и до формирования главного окна приложения.

В результате установленные настройки будут сразу же применены к новому пользователю.

Вот пример кода:

Процедура УстановкаПараметровСеанса(ТребуемыеПараметры)

   Настройки = ХранилищеСистемныхНастроек.Загрузить(
            “Общее/НастройкиКлиентскогоПриложения”);
   Если Настройки=Неопределено Тогда
      Настройки = Новый НастройкиКлиентскогоПриложения;
      Настройки.ОтображатьПанелиНавигацииИДействий = Ложь;
      Настройки.ОтображатьПанельРазделов = Истина;
      Настройки.РежимОткрытияФормПриложения=
              РежимОткрытияФормПриложения.Закладки;
      ХранилищеСистемныхНастроек.Сохранить(
             “Общее/НастройкиКлиентскогоПриложения”,,Настройки);
   КонецЕсли;

КонецПроцедуры

Еще несколько сотен таких разобранных вопросов:

Курс Профессиональная разработка отчетов в 1С 8.3 на Системе Компоновки Данных (СКД)

Поддержка: 60 дней. Стоимость: 3900 рублей.

Курс Профессиональная разработка интерфейсов и форм в 1С:Предприятии 8.3

Поддержка: 45 / 90 дней. Стоимость: 4900 / 8700 рублей.

Несколько вопросов из Мастер-группы курса
Профессиональная разработка отчетов в 1С 8.3 на Системе Компоновки Данных (СКД)

Вопрос 1

Для чего могут потребоваться пользовательские поля, если в схеме компоновки можно использовать ресурсы и вычисляемые поля?

MG-Questions-SKD-01

Ответ:

Главная особенность пользовательских полей в том, что их можно настраивать в режиме «1С:Предприятие» – то есть нет необходимости редактировать саму схему компоновки в конфигураторе.

В пользовательском режиме можно создать новое поле, которое разработчик не определил в схеме компоновки.

Для этого нужно обратиться к окну изменения варианта отчета, добавить новое пользовательское поле и указать, как для этого поля будут рассчитываться детальные и итоговые записи:

MG-Questions-SKD-02

Полученное поле можно использовать в отчете:

MG-Questions-SKD-03

Затем настроенный вариант отчета с новым добавленным полем можно сохранить.

Все эти действия можно выполнить в режиме «1С:Предприятие», без обращения к конфигуратору. С этой точки зрения пользовательское поле-выражение похоже на вычисляемое поле и ресурс. Если для пользовательского поля задано выражение итоговых записей, то в списке доступных и выбранных полей оно будет отображаться при помощи зеленой пиктограммы (как ресурс).

Но создать новое вычисляемое поле, задать или изменить выражение для ресурса в режиме «1С:Предприятие» нельзя. Для этого потребуется обратиться к конструктору схемы компоновки.

Вопрос 2

Как настроить форму отчета таким образом, чтобы в быстрых пользовательских настройках для отборов отображался вид сравнения?

Ответ:

Перейти к виду сравнения для быстрых пользовательских настроек можно при помощи команды на форме «Еще» — «Изменить форму»:

MG-Questions-SKD-04

MG-Questions-SKD-05

По умолчанию вид сравнения скрыт.

Разработчики платформы обосновывают это следующим допущением.

Если у отбора установлен вид сравнения «Равно», то пользователю нужно иметь возможность быстро вводить значение и не отвлекаться на вид сравнения. А если ему нужно изменить вид сравнения, то для этого следует воспользоваться формой настроек. Эта же форма используется для редактирования и других «не быстрых» настроек.

Например, в УТ 11.2 (БСП) выбор вида сравнения реализован при помощи контекстного меню:

MG-Questions-SKD-06

Вопрос 3

Если в отчете «ОстаткиТоваровНаСкладах» установить выражение представления для поля «Количество»:

Строка(Количество) + "%"

то при формировании отчета символ «%» не выводится. В чем может быть дело?

MG-Questions-SKD-07

MG-Questions-SKD-08

Ответ:

Причина такого поведения системы в том, что выражение представления влияет только на вывод детальных записей.

А в настройках компоновки используется группировка, а не детальные записи.

Поэтому, чтобы получить символ «%» в итоговом отчете, можно использовать два варианта.

Первый вариант – в настройках структуры отчета воспользоваться детальными записями:

MG-Questions-SKD-09

Тогда в отчете в колонке «Количество» будет использоваться выражение представления:

MG-Questions-SKD-10

Второй вариант – изменить выражение для ресурса «Количество»:

Строка(Сумма(Количество)) + "%"

А для более красивого представления можно использовать такое выражение:

Формат(ЕстьNull(Сумма(Количество), 0), "ЧДЦ=2; ЧН=0,00") + "%"

MG-Questions-SKD-11

Тогда отчет будет выглядеть следующим образом:

MG-Questions-SKD-12

Вопрос 4

Отчет строится по оборотному регистру накопления «Продажи». Для ресурсов используются следующие выражения:

MG-Questions-SKD-13

В настройках структуры отчета дважды используются детальные записи (первый раз – как подчиненная группировка, второй раз – как отдельная группировка):

MG-Questions-SKD-14

При этом данные в отчет выводятся по-разному. В первом случае в детальных записях указывается количество документов, а во втором – сам Регистратор:

MG-Questions-SKD-15

В чем причина такого поведения системы?

Ответ:

Вы столкнулись с особенностью использования детальных записей.

Детальные записи – это группировка без указанных группировочных полей. Если для детальных записей в списке выбранных полей присутствуют только ресурсы, то такая группировка будет рассматриваться как «общий итог», будет выводиться всего одна запись с итогом по выбранным ресурсам.

Для детальных записей, подчиненных «Контрагенту», в списке выбранных полей используется «Автополе».

Если развернуть его, то можно увидеть, что оно состоит из двух ресурсов («Регистратор» и «Количество»). Получается, что в группировке есть только ресурсы, поэтому в первом случае система выводит только итог по этим ресурсам.

На уровне детальных записей, вложенных в «Контрагента», в выбранных полях можно удалить «Автополе», добавить явно поля «Контрагент», «Регистратор» и «Количество»:

MG-Questions-SKD-16

Тогда в этой группировке система будет выводить представление регистратора, а не значение агрегатной функции:

MG-Questions-SKD-17

Вопрос 5

В запросах для источников данных параметры виртуальных таблиц заданы в явном виде, также добавлены параметры типа «Стандартный период» для быстрого ввода.

На закладке «Параметры» все равно кроме этого присутствуют параметры «НачалоПериода» и «КонецПериода», которых нет в тексте запроса. Как можно их убрать из списка параметров?

MG-Questions-SKD-18

Ответ:

Автоматическое добавление параметров «НачалоПериода» и «КонецПериода» связано с использованием автозаполнения в наборе данных.

При установленном флажке «Автозаполнение» в схему компоновки автоматически добавляются параметры виртуальных таблиц с соответствующими именами («НачалоПериода», «КонецПериода», «Период» и т.д.).

Управлять поведением системы можно при помощи конструкций в фигурных скобках (расширение языка запросов для системы компоновки). Возьмем для примера вот такой фрагмент:

РегистрНакопления.Продажи.Обороты(&НачалоПериодаТекущий)

Для системы это значит:

РегистрНакопления.Продажи.Обороты(&НачалоПериодаТекущий {&НачалоПериода}, {&КонецПериода})

Т.е. значение параметра «НачалоПериодаТекущий» используется, только если в настройках не установлено значение параметра «НачалоПериода».

За этим нужно внимательно следить, потому что можно сформировать отчет, в котором данные будут выводиться не за тот интервал времени, за который ожидается их получить.

Чтобы в списке параметров не было «НачалоПериода» и «КонецПериода», нужно изменить тексты запросов наборов данных, указать параметры виртуальных таблиц в фигурных скобках:

ВЫБРАТЬ
   ПродажиОбороты.Номенклатура,
   ПродажиОбороты.СуммаОборот КАК ТекущееЗначение
ИЗ
   РегистрНакопления.Продажи.Обороты({&НачалоПериодаТекущий}, {&КонецПериодаТекущий}, , ) КАК ПродажиОбороты

ВЫБРАТЬ
   ПродажиОбороты.Номенклатура,
   ПродажиОбороты.СуммаОборот КАК ПредыдущееЗначение
ИЗ
   РегистрНакопления.Продажи.Обороты({&НачалоПериодаПредыдущий}, {&КонецПериодаПредыдущий}, ,) КАК ПродажиОбороты

В таком случае список параметров выглядит следующим образом:

MG-Questions-SKD-19

Вопрос 6

Разрабатывается отчет по остаткам товаров на складах. В отчет выводятся группировки по складу и номенклатуре, детальные записи и общий итог по количеству:

MG-Questions-SKD-20

Для ресурса «Количество» используется следующее выражение:

Выбор Когда Количество > 0 Тогда Сумма(Количество) Иначе 0 Конец

При этом итоги в отчет выводятся не так, как ожидается, а общий итог вообще не выводится:

MG-Questions-SKD-21

В чем ошибка?

Ответ:

Здесь ошибка в выражении для ресурса: неправильно указано, к чему будет применяться агрегатная функция «Сумма».

Использование просто полей в выражении для расчета итогов обычно не имеет смысла, поскольку на уровне группировки требуется рассчитать сумму (или другую агрегатную функцию) по детальным записям.

Нужно изменить выражение для ресурса на следующее:

Сумма(Выбор Когда Количество > 0 Тогда Количество Иначе 0 Конец)

MG-Questions-SKD-22

В таком случае система будет рассчитывать итог по группировке следующим образом.

Обходятся все записи, для каждой выполняется проверка: если Количество > 0, будет использоваться само значение Количество, иначе будет использоваться значение 0. Полученные значения складываются. Так будет получен итог по группировке.

То есть, чтобы получить корректный итог, нужно использовать агрегатную функцию, а условное выражение указать внутри нее.

Тогда получится ожидаемый результат:

MG-Questions-SKD-23

Вопрос 7

Предположим, у нас стоит задача выводить остатки товара в кросс-таблицу, где в строках выведены группировки по номенклатуре, а в колонках — по складу и организации.

Каким образом можно организовать группировки в колонках так, чтобы группировка верхнего уровня (склад) накрывала шапкой группировки нижнего уровня (организация)?

Пример на рисунке.

MG-Questions-SKD-24

Ответ:

Можно задать следующую структуру отчета:

MG-Questions-SKD-25

Тогда отчет будет отображаться следующим образом:

MG-Questions-SKD-26

Он отличается от требуемого только тем, что не объединены расположенные рядом ячейки с одинаковым складом.

Чтобы ячейки со складами были объединенными, можно использовать предопределенный макет схемы компоновки и программную обработку готового сформированного табличного документа.

Зададим имя Организация для группировки в колонках таблицы:

MG-Questions-SKD-27

Чтобы «накрыть шапкой» такие колонки, воспользуемся макетом заголовка:

MG-Questions-SKD-28

В ячейках указываются шаблоны и специальные «маркеры» — символы «??».

После того, как весь табличный документ выведен, осуществляется поиск соседних ячеек с одинаковым текстом, начинающимся с «??».

Эти ячейки объединяются, получается общая шапка для колонок.

Пример программного кода в модуле отчета приведен ниже:

Программный код


Функция НужноОбъединятьЯчейки(ТабДок, ИндексСтроки, ИндексКолонки)

ТекущаяЯчейка = ТабДок.Область(ИндексСтроки, ИндексКолонки);
СледующаяЯчейка = ТабДок.Область(ИндексСтроки, ИндексКолонки + 1);

Если НЕ ЗначениеЗаполнено(ТекущаяЯчейка.Текст) Тогда

Возврат Ложь;

ИначеЕсли ТекущаяЯчейка.Текст = СледующаяЯчейка.Текст
И ТекущаяЯчейка.Имя = "R" + ИндексСтроки + "C" + ИндексКолонки
И Лев(ТекущаяЯчейка.Текст, 2) = "??" И Лев(СледующаяЯчейка.Текст, 2) = "??" Тогда

Возврат Истина;

Иначе

Возврат Ложь;

КонецЕсли;

КонецФункции

Процедура ОбъединитьЯчейкиВШапке(ТабДок)

Для ИндексСтроки = 1 По ТабДок.ВысотаТаблицы Цикл

НачальнаяКолонка = 0;
Для ИндексКолонки = 1 По ТабДок.ШиринаТаблицы Цикл

Если НужноОбъединятьЯчейки(ТабДок, ИндексСтроки, ИндексКолонки) Тогда

Если НЕ НачальнаяКолонка Тогда
НачальнаяКолонка = ИндексКолонки;
КонецЕсли;

ИначеЕсли НЕ НачальнаяКолонка = 0 Тогда

ТекстЗаголовка = ТабДок.Область(ИндексСтроки, ИндексКолонки).Текст;
ТекстЗаголовка = Сред(ТекстЗаголовка, 3, СтрДлина(ТекстЗаголовка) - 2);
// уберем из заголовка "??"

ОбъединяемаяОбласть = ТабДок.Область(ИндексСтроки, НачальнаяКолонка,
ИндексСтроки, ИндексКолонки);
ОбъединяемаяОбласть.Объединить();
ОбъединяемаяОбласть.ГоризонтальноеПоложение = ГоризонтальноеПоложение.Центр;
ОбъединяемаяОбласть.Текст = ТекстЗаголовка;
НачальнаяКолонка = 0;

Иначе

ТекстЗаголовка = ТабДок.Область(ИндексСтроки, ИндексКолонки).Текст;
Если Лев(ТекстЗаголовка, 2) = "??" Тогда

ТекстЗаголовка = Сред(ТекстЗаголовка, 3, СтрДлина(ТекстЗаголовка) - 2);
// уберем из заголовка "??"

Область = ТабДок.Область(ИндексСтроки, НачальнаяКолонка,
ИндексСтроки, ИндексКолонки);
Область.Текст = ТекстЗаголовка;

КонецЕсли;
НачальнаяКолонка = 0;

КонецЕсли;

КонецЦикла;

Если НЕ ОбъединяемаяОбласть = Неопределено Тогда
Продолжить;
КонецЕсли;

КонецЦикла;

КонецПроцедуры

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

СтандартнаяОбработка = Ложь;

НастройкиКомпоновки = КомпоновщикНастроек.ПолучитьНастройки();

КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиКомпоновки,
ДанныеРасшифровки);

ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки);

ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
ПроцессорВывода.Вывести(ПроцессорКомпоновки);

ОбъединитьЯчейкиВШапке(ДокументРезультат);

КонецПроцедуры


Здесь используется программное формирование отчета, после чего дорабатывается полученный табличный документ, объединяются соседние ячейки с одинаковым текстом, начинающимся с «??».

Получается вот такой отчет:

MG-Questions-SKD-29

Вопрос 8

В схеме компоновки используется набор данных – объединение, при помощи которого получаются продажи за два периода.

Было добавлено два вычисляемых поля:

MG-Questions-SKD-30

Для этих вычисляемых полей на закладке «Ресурсы» заданы выражения:

MG-Questions-SKD-31

Но при формировании отчета поле Отклонение (%) не выводится:

MG-Questions-SKD-32

В чем причина?

Ответ:

Чтобы разобраться, почему получается такой результат, добавим в настройки компоновки подчиненную группировку (Детальные записи), в выбранных полях укажем поле Номенклатура:

MG-Questions-SKD-33

Тогда отчет будет выглядеть следующим образом:

MG-Questions-SKD-34

Теперь видно, почему на уровне группировки не заполняется Отклонение (%).

Поскольку используется объединение двух наборов данных, на уровне детальных записей мы получаем две строки.

Для каждой строки рассчитывается вычисляемое поле. На уровне группировки простое суммирование отклонений даст неправильный результат.

Чтобы получить корректный результат, нужно изменить выражения для ресурса:

MG-Questions-SKD-35

При таких настройках в отчет попадут следующие данные:

MG-Questions-SKD-36

Исходники:

Курс Профессиональная разработка отчетов в 1С 8.3 на Системе Компоновки Данных (СКД)

Поддержка: 60 дней. Стоимость: 3900 рублей.

Курс Профессиональная разработка интерфейсов и форм в 1С:Предприятии 8.3

Поддержка: 45 / 90 дней. Стоимость: 4900 / 8700 рублей.

PDF-версия статьи для участников группы ВКонтакте

Мы ведем группу ВКонтакте - http://vk.com/kursypo1c.

Если Вы еще не вступили в нее - сделайте это сейчас, и в блоке ниже (на этой странице) появится ссылка на скачивание материалов.


17 вопросов и ответов - в PDF-форматеСтатья в PDF-формате
Вы можете скачать эту статью в формате PDF по следующей ссылке: Ссылка доступна для зарегистрированных пользователей)

Если Вы уже участник группы - нужно просто повторно авторизоваться в ВКонтакте, чтобы скрипт Вас узнал. В случае проблем решение стандартное: очистить кэш браузера или подписаться через другой браузер.

48 комментариев к “17 вопросов и ответов по СКД, проектированию форм, навигации, панелям и т.п.

  1. pr0nik сказал:

    Здравствуйте.
    А как насчет такого вопроса. В СКД 2 набора данных соединены на закладке связи наборов данных. Если в наборе приемнике нет данных, то мы получаем NULL. Каким образом можно превратить этот NULL в 0 или другое значение, по аналогии с ЕСТЬNULL(ПолеИзПремника,0) в запросе? Нужно чтобы, например, работал отбор вида ПолеИзПремника= 0

    • Василий Ханевич сказал:

      Добрый день!
      Можно создать собственное вычисляемое или пользовательское поле, где и использовать функцию ЕСТЬNULL.

      • pr0nik сказал:

        Уже пытался так сделать, И только что перепроверил.
        в вычисляемом поле КоличествоОборот1 пишу ЕстьNULL(КоличествоОборот,0), в ресурсе КоличествоОборот1 пишу Сумма(ЕстьNULL(КоличествоОборот,0)
        Значение действительно приводится к 0 это видно если используя условное оформление раскрасить отчет.
        Но при указании в отборе на уровне отчета КоличествоОборот1=0 в результат ничего не попадает. Хотя без отбора в результате есть строки где КоличествоОборот1=0 .
        Спасибо, теперь можно хотя бы подсветить позиции в отчете, частично вопрос закрыт.

        • Василий Ханевич сказал:

          Тут дело в особенностях работы системы компоновки.

          Поскольку отбор установлен на поле набора – приемника связи, то система компоновки применяет элементы оптимизации, в макете компоновки по факту используется внутренняя связь между наборами данных, а не внешняя левая. Выполняется запрос из набора – источника связи, затем выполняется запрос из набора – приемника связи с отбором. Получается пустой результат. В результате внутреннего соединения между наборами будет тоже пустой результат.

          Получается, что система не даст сделать такой отбор.
          Попробуйте заменить соединение наборов на объединение. Для объединения такой отбор будет работать. Прикрепил пример – ОтборОбъединение.zip.

          • pr0nik сказал:

            К сожалению обеднение не вариант потому как соединение использовано как в видео 19. Срез последних на каждую дату из 10 занятия курса по СКД. За тем лишь отличием что я получаю обороты за периоды полученные в запросе источнике.
            В принципе мне удалось выкрутится в данной ситуации применив отбор не на уровне отчета а на уровне самой нижней группировки, но пришлось отключить отражение итогов потому как итоги считаются по все данным отчета.

  2. AlexPC сказал:

    Добрый день.

    А можно разобрать ситуацию с расположением ресурсов среди других полей с отображением итогов по вертикали. Кроме решения с собственным макетом есть другие варианты. Я перепробовал многие настройки на закладке дополнительно, но не могу добиться желаемых результатов.
    Отчет простой – группировка по детальным записям.

    • Василий Ханевич сказал:

      Добрый день!
      В Других настройках установите параметр Авто позиция ресурсов в значение Не использовать. Тогда поля будут отображаться в том порядке, как они перечислены в выбранных полях.

    • AlexPC сказал:

      Разобрался. Не понял почему, но при отключении автопозиции ресурсов вчера не срабатывал порядок полей, указанных в выбранных полях. Можете что-нибудь добавить к этому?

      • Василий Ханевич сказал:

        Если на закладке Другие настройки галочка использования для этого параметра не установлена, то по умолчанию ресурсы будут выводиться последними.

  3. Денис сказал:

    Ответ на вопрос №1
    “Сообщение.Поле = «ИмяРеквизитаФормы»;”
    “ИмяРеквизитаФормы”?? Что-то не работает… Сообщение.Поле = “ПутьКДаннымРеквизитаФормы” – работает! Платформа 8.3.8.2088.

    • Сергей Калинкин сказал:

      Добрый день, Денис!
      Уточните пожалуйста, что такое “ПутьКДаннымРеквизитаФормы”? Мне такой термин неизвестен.

  4. Дмитрий сказал:

    Хм… Вопрос №9 из первого блока – когда-то уже возникала у меня такая необходимость, нашел подобное решение, но увы – не работает. Грешил на сырую платформу (работали тогда на 8.3.4.*). Сейчас попробовал на 8.3.8 – специально создал нового юзера – результат нулевой. В чем может быть дело?

    • Сергей Калинкин сказал:

      Добрый день, Дмитрий!
      Данный код предназначен для классического управляемого интерфейса версии 8.2, в Такси он работать не будет.

      Для Такси можно применить следующий код:

      Процедура УстановкаПараметровСеанса(ТребуемыеПараметры)
         
          Настройки = ХранилищеСистемныхНастроек.Загрузить("Общее/НастройкиИнтерфейсаКлиентскогоПриложения");
          Если Настройки=Неопределено Тогда
             
              Настройки = Новый НастройкиИнтерфейсаКлиентскогоПриложения;
              СоставПанелей = Новый НастройкиСоставаИнтерфейсаКлиентскогоПриложения;
              СоставПанелей.Верх.Добавить(Новый  ЭлементНастройкиСоставаИнтерфейсаКлиентскогоПриложения("ПанельРазделов"));
              СоставПанелей.Низ.Добавить(Новый  ЭлементНастройкиСоставаИнтерфейсаКлиентскогоПриложения("ПанельОткрытых"));
              Настройки.УстановитьСостав(СоставПанелей);
             
              ХранилищеСистемныхНастроек.Сохранить("Общее/НастройкиИнтерфейсаКлиентскогоПриложения",,Настройки);
         
          КонецЕсли;
         
      КонецПроцедуры
          • Дмитрий сказал:

            УТП (не на УФ), в которой добавлена подсистема для торговых представителей с небольшим набором прав и доступом к двум документам и одному отчету. Т.е. по сути это один рабочий стол с двумя дин. списками – панели разделов и задач там не нужны, вот и пытаюсь побороть :)

            • Сергей Калинкин сказал:

              Добрый день, Дмитрий!
              Уточните пожалуйста:
              1. Версию используемой платформы
              2. Режим совместимости, который установлен в свойствах конфигурации (8.3.7, 8.3.6 …)
              3. Режим управляемого интерфейса (в закладках или в отдельных окнах, для этого в пользовательском режиме в упр. интерфейсе войдите в меню Сервис-Параметры)

              • Дмитрий сказал:

                Добрый день. Версия платформы 8.3.8.1784, режим совместимости не используется, режим совместимости интерфейса – “Версия 8.2. Разрешить такси”.
                В настройках внешнего вида – формы в закладках. Причем изменить не получается – после выбора “В отдельных окнах” и перезапуска – опять стоит “В закладках”. Этого бага, кстати, я и не видел раньше, т.к. в нашем случае нужно использовать закладки (приложение запускается в терминале с отключенным рабочим столом Windows) .
                В самописной конфигурации с такими же режимами совместимости и на этой же платформе – такого нет, работают оба режима – и в окнах и в закладках… Более того, панели этим методом отключаются!
                Значит проблема где-то в типовой (возможно “Основной режим запуска – обычное приложение” в свойстве конфигурации?), так как в изначально написанной под УФ конфигурации код работает, хоть он там мне и не нужен :)

                • Сергей Калинкин сказал:

                  Добрый день!
                  Судя по всему в коде вашей конфигурации присутствует код по настройке видимости панелей. Попробуйте глобальным поиском по модулям поискать строку “НастройкиКлиентскогоПриложения”.

  5. SomeOne сказал:

    Здравствуйте
    А что подразумевает под собой “Поддержка”?
    “Поддержка: 45 / 90 дней. Стоимость: 4900 / 8700 рублей.”

    • Татьяна Гужавина сказал:

      Доброго дня, Леонид!
      «Поддержка: 45 / 90 дней. Стоимость: 4900 / 8700 рублей.»
      В зависимости от версии курса будет разный период поддержки от преподавателя.
      В рамках поддержки Вы сможете задавать вопросы преподавателю на сайте по материалам курса, увидите ответы на вопросы других участников.
      Также в курсе есть практические задания. Отчитываетесь об их выполнении на сайте, после одобрения отчета, Вы получаете доступ к решению преподавателя.

      • stopa85 сказал:

        Какие-то сертификаты после прохождения курса будут? Электронные или бумажные?

        • Кузьмин Сергей сказал:

          Да, в курсе по СКД предусмотрен сертификат о прохождении курса в случае выполнения всех практических заданий, в том числе финального. Сертификат высылается в электронном виде на электронную почту.

  6. kukuepta сказал:

    а вот интересный вопрос по закладке прочих настроек:
    расположение общих итогов по горизонтали(вертикали) – отключаешь один, например вертикальный, пропадают оба. почему?

    • Василий Ханевич сказал:

      Добрый день!
      В настройках компоновки задаю значения параметров следующим образом:
      Настройки
      Результирующий отчет при этом выглядит следующим образом:
      Отчет
      Т.е. выключены общие итоги по вертикали, а общие итоги по горизонтали не настраиваем. Отчет выводится в соответствии с этими настройками – итогов по вертикали нет, а итоги по горизонтали выводятся.
      Какие настройки используются в вашем случае? Как воспроизвести некорректное поведение системы?

  7. Владислав сказал:

    Хороший материал. Как минимум – равноценная замена бесплатному видео, а, скорее, и поинтереснее будет.
    Будет хорошо, если подобные материалы будут появляться и впредь.

    • Евгений Гилев (Мастер-тренер) сказал:

      Не успели подготовить.
      Постараемся сделать на выходных.

  8. Александр сказал:

    Очень интересно.
    Что-то встречал сам, но ответ на вопрос 7 из второй части меня поразил.

    • Николай сказал:

      Тоже зацепило. Интересно, это стандартный прием? Не встречал его до этого ни в какой литературе.

      • Василий Ханевич сказал:

        Добрый день!
        Стандартно система при настройках, как в 7-м вопросе, не “накрывает шапкой” группировку нижнего уровня, а выводит их на одном уровне. Это не всегда наглядно, поэтому приходится прибегать к доработкам. А вот вариантов, как именно реализовать объединение ячеек, может быть несколько, в зависимости от особенностей решаемой задачи и от требуемого вида отчета. В примере использовались специальные маркеры, чтобы объединять только нужные ячейки, а не все подряд соседние ячейки с одинаковым текстом. Еще вариант – для оптимизации изменить алгоритм, чтобы поиск происходил не во всем табличном документе, а только в шапке.

Добавить комментарий

Ваш e-mail не будет опубликован. Обязательные поля помечены *

Мы используем файлы cookies, чтобы сделать сайт удобнее.
Продолжая просмотр сайта, Вы соглашаетесь с их использованием.
Подробнее